使用UTL_SMTP包实现存储过程邮件发送

注意：使用QQ邮箱的话密码需要第三方验证方式才能通过哦

验证 方式：http://service.mail.qq.com/cgi-bin/help?subtype=1&&id=28&&no=1001256

1、安装UTL_MAIL包

UTL_MAIL是在Oracle 10g推出的新邮件发送开发包。之前Oracle 8i开始，支持使用utl_smtp包进行RFC所定义的简单邮件传输协议（SMTP）。使用UTL_MAIL要简单与传统方式，免除很多额外工作。

默认情况下，UTL_MAIL工具包是没有安装到Oracle程序包中的，如果需要使用需要额外进行安装。安装的方法是在sys用户下，调用$ORACLE_HOME/rdbms/admin目录下的两个脚本文件。

SQL> conn / as sysdba;

SQL> @$ORACLE_HOME/rdbms/admin/utlmail.sql

Package created.

Synonym created.

SQL> @$ORACLE_HOME/rdbms/admin/prvtmail.plb

Package created.

Package body created.

Grant succeeded.

Package body created.

 

No errors.

sys用户下创建

CREATE OR REPLACE PROCEDURE PRC_sendmail

(

    p_receiver  VARCHAR2,     -- 邮件接收人

    p_subject   VARCHAR2,     -- 邮件标题

    p_message   VARCHAR2      -- 邮件正文

)

IS

    --下面四个变量请根据实际邮件服务器进行赋值

    v_smtphost           VARCHAR2(30)       := 'smtp.qq.com';                  --SMTP服务器地址(hotmail为smtp.live.com,测试未通过)

    v_smtpport           number(5)          :=25;                                       --smtp服务端口

    v_user               VARCHAR2(30)       := '630730701@qq.com';          --登录SMTP服务器的用户名

    v_pass               VARCHAR2(20)       := 'xxxxryngpsxqxxxx';         --登录SMTP服务器的密码--QQ邮箱的话要使用第三方验证方式才行

    v_sender             VARCHAR2(50)       := '630730701@qq.com';         --发送者邮箱，一般与 ps_user 对应

    v_conn               UTL_SMTP.connection;                                           --到邮件服务器的连接

    v_msg                varchar2(4000);                                                    --邮件内容

    

BEGIN

    v_conn := UTL_SMTP.open_connection(v_smtphost, v_smtpport);

    --是用 ehlo() 而不是 helo() 函数

    --否则会报：ORA-29279: SMTP 永久性错误: 503 5.5.2 Send hello first.

    UTL_SMTP.ehlo(v_conn, v_smtphost); 

    -- smtp服务器登录校验

    UTL_SMTP.command(v_conn, 'AUTH LOGIN');            

    UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));

    UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));

    --设置发件人及收件人

    UTL_SMTP.mail(v_conn, '<'||v_sender||'>');

    UTL_SMTP.rcpt(v_conn, '<'||p_receiver||'>');

    -- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行

    v_msg :='Date:'|| TO_CHAR(SYSDATE, 'yyyy mm dd hh24:mi:ss')

            || UTL_TCP.CRLF || 'From: '|| v_sender || ''

            || UTL_TCP.CRLF || 'To: ' || p_receiver || ''

            || UTL_TCP.CRLF || 'Subject: ' || p_subject

            || UTL_TCP.CRLF || UTL_TCP.CRLF          -- 这前面是报头信息

            || p_message;                                        -- 这个是邮件正文

    --打开流

    UTL_SMTP.open_data(v_conn); 

    --标题和内容都都可用中文                                   

    UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg));  

    --关闭流 

    UTL_SMTP.close_data(v_conn);  

    --关闭连接                                 

    UTL_SMTP.quit(v_conn);                                         

EXCEPTION

 WHEN OTHERS THEN

     DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);

     DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);

     UTL_SMTP.quit(v_conn);

END PRC_sendmail;

sys用户下调用：

exec PRC_sendmail(p_receiver => '630730701@qq.com',p_subject => 'ORACLE发送邮件',p_message => '第一个用oracle发送的邮件成功了');

参考博客1：http://blog.itpub.net/17203031/viewspace-700327/

参考博客2：http://blog.chinaunix.net/uid-23072872-id-3576270.html