asp中Scripting.Dictionary字典对象使用示例

vbscript的Scripting.Dictionary创建了类似于Key索引对应Value值的字典对象，通过Key直接索引到指定的Value。

VBScript中Scripting.Dictionary使用示例如下:

Dim objDict
Set objDict = WSH.CreateObject("Scripting.Dictionary")
' .Add(key, value)
objDict.Add "a", "value1"
objDict.Add "b", "value2"
objDict.Add "c", "value3"
'直接通过key=b索引到value2
WSH.Echo objDict.Item("b")
objDict.Remove "b" ' 删除索引b及其对应的值

' 以下是遍历字典
Dim objKeys, objItems, i
objKeys = objDict.Keys
objItems = objDict.Items
For i = 0 To objDict.Count -1
WSH.Echo "Key=" & objKeys(i) &_
" AND Value=" & objItems(i)
Next
' 判断指定的key是否存在
If objDict.Exists("b") Then
WSH.Echo "Found it"
Else
WSH.Echo "Not Exists!"
End If
objDict.RemoveAll  ' 清空字典内所有的key及其对应value
Set objDict = Nothing

当然在JScript访问的方式一样，但是在遍历这里需要一点点变动。

var dict = WSH.CreateObject("Scripting.Dictionary");
dict.Add("a", "value1");
dict.Add("b", "value2");
dict.Add("c", "value3");
WSH.Echo(dict.Item("b"));
dict.Remove("b");

// 注意这里的遍历
var keys = new VBArray(dict.Keys());
var items = new VBArray(dict.Items());

for (var i=0; i < dict.Count; i++) {
WSH.Echo("Key=" + keys.getItem(i) +
" AND Value=" + items.getItem(i));
}

if (dict.Exists("b")) {
WSH.Echo("Found it");
} else {
WSH.Echo("Not Exists!");
}

dict.RemoveAll();

Dim objDict
Set objDict = WSH.CreateObject("Scripting.Dictionary")
objDict.Add "b", Array("1","2","3")
WSH.Echo objDict.Item("b")(0)
WSH.Echo objDict("b")(1)
objDict.RemoveAll
Set objDict = Nothing