Arduino 各种模块篇 大气压强模块 pressure sensor BMP085

this tutorial is very neat.

Mine is like this :



While the one from sparkfun is like this:





Anyway their circuit are almost the same.(The blue one's better for safty )

So the codes are functional for those two different coloured board.

BMP085 Pin	Pin Function
VCC	Power (1.8V-3.6V)
GND	Ground
EOC	End of conversion output
XCLR	Master Clear (low-active)
SCL	Serial Clock I/O
SDA	Serial Data I/O

BMP085 Pin	Arduino Pin
VCC	3.3V
GND	GND
SCL	A5
SDA	A4

For now, we're going to ignore XCLR and EOC, it's safe to just leave them unconnected.

[b]For more info, YOU DO NEED : https://www.sparkfun.com/tutorials/253[/b]
You may need to download all the codes here here, (of one .ino arduino IDE file)

here's the codes:

/* BMP085 Extended Example Code
by: Jim Lindblom
SparkFun Electronics
date: 1/18/11
updated: 2/26/13
license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/ 
Get pressure and temperature from the BMP085 and calculate
altitude. Serial.print it out at 9600 baud to serial monitor.

Update (7/19/11): I've heard folks may be encountering issues
with this code, who're running an Arduino at 8MHz. If you're
using an Arduino Pro 3.3V/8MHz, or the like, you may need to
increase some of the delays in the bmp085ReadUP and
bmp085ReadUT functions.
*/

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;

// Use these for altitude conversions
const float p0 = 101325;     // Pressure at sea level (Pa)
float altitude;

void setup()
{
Serial.begin(9600);
Wire.begin();
bmp085Calibration();
}

void loop()
{
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));

Serial.print("Temperature: ");
Serial.print(temperature, DEC);
Serial.println(" *0.1 deg C");
Serial.print("Pressure: ");
Serial.print(pressure, DEC);
Serial.println(" Pa");
Serial.print("Altitude: ");
Serial.print(altitude, 2);
Serial.println(" m");
Serial.println();

delay(1000);
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;

x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;

return ((b5 + 8)>>4);
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;

b6 = b5 - 4000;
// Calculate B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

// Calculate B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
p = (b7<<1)/b4;
else
p = (b7/b4)<<1;

x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;

return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
unsigned char data;

Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();

Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available())
;

return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;

Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(address);
Wire.endTransmission();

Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2)
;
msb = Wire.read();
lsb = Wire.read();

return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
unsigned int ut;

// Write 0x2E into Register 0xF4
// This requests a temperature reading
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x2E);
Wire.endTransmission();

// Wait at least 4.5ms
delay(5);

// Read two bytes from registers 0xF6 and 0xF7
ut = bmp085ReadInt(0xF6);
return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;

// Write 0x34+(OSS<<6) into register 0xF4
// Request a pressure reading w/ oversampling setting
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF4);
Wire.write(0x34 + (OSS<<6));
Wire.endTransmission();

// Wait for conversion, delay time dependent on OSS
delay(2 + (3<<OSS));

// Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.write(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);

// Wait for data to become available
while(Wire.available() < 3)
;
msb = Wire.read();
lsb = Wire.read();
xlsb = Wire.read();

up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

return up;
}

the Serial output when the data is approaching to a stable level:



Here i get Temperature, Pressure, Altitude.

I use google earth to find out at my position the altitude would be around 105 metres.

Either one is right.

Or other accurate sensors or measuring in other methods will give us the most right accurate result.

As we all know that the altitude is caculated out from the pressure.

in different seasons and on different weather, the pressure could be different.

So the altitude i got would not be very accurate.

Google earth maybe use the technology of promixity, ray or etc.. This result could be more accurate than that caculated out from the pressure inderectly.

Here we just have a test individually.

If I put the sensor into a bag and blow some air into the bag,



we will see :



The altitude will decrease.

Somehow it comes to an altitude below 0 metre(s). e.g. -13.23m ( coz there are too much air in the bag. The lower Altitude is, the higher air pressure will be. )

You could check it out. Temperature, Pressure, Altitude.

Here's the basic function









As for some info in Chinese language:

资料自行下载http://www.kuaipan.cn/file/id_61649243307246089.html

[b][b]1、板载BMP085数字式气压传感器，内置AD转换器，支持IIC通信协议[/b][/b]

[b][b]2、模块可以测试大气气温和大气压强,[/b][/b]

[b][b] PCB采用沉金工艺。pcb尺寸18.5mm*18mm[/b][/b]

[b][b]3、支持5V/3.3V电压输入[/b][/b]

[b][b]4、常用的引脚已经引出，插针为标准2.54mm[/b][/b]

It's brief introduction :

BMP085 是一款高精度、超低能耗的压力传感器，可以应用在移动设备中。它的性能卓越，绝对精度最低可以达到0.03hPa，并且耗电极低，只有3μA。 BMP085采用强大的8-pin陶瓷无引线芯片承载（LCC）超薄封装，可以通过I2C总线直接与各种微处理器相连。

主要特点:

压力范围：300 － 1100hPa（海拔9000米至-500米）

电源电压：1.8V － 3.6V（VDDA）

1.62V － 3.6V（VDDD）

LCC8封装：无铅陶瓷载体封装（LCC）

尺 寸： 5.0mmx5.0x1.2mm

低功耗： 5μA 在标准模式

高精度: 低功耗模式下，分辨率为0.06hPa（0.5米）

高线性模式下，分辨率为0.03hPa（0.25米）

含温度输出

I2C接口

温度补偿

无铅，符合RoHS规范，

MSL 1

反应时间：7.5ms

待机电流：0.1μA

无需外部时钟电路

典型应用:

1.GPS精确导航（航位推算，上下桥检测等）

2.室内室外导航

3.休闲、体育和医疗健康等监测

4.天气预报

5.垂直速度指示（上升/下沉速度）

6.风扇功率控制