为部署vista SP1和windows 2008升级SCCM2007

原文地址
http://blogs.technet.com/deploymentguys/archive/2008/04/18/updating-system-center-configuration-manager-2007-for-windows-vista-service-pack-1-and-windows-server-2008-deployment.aspx

The SCCM 2007 Operating System Deployment components use the Windows Automated Installation Toolkit (WAIK) for creating, managing, and deploying Windows Imaging (WIM) images. SCCM 2007 setup installs the Windows Vista RTM WAIK (WAIK 1.0) during installation if it is not already installed. In order to deploy Windows Vista SP1 and Windows Server 2008 with SCCM 2007, the WAIK must be updated to the latest version (WAIK 1.1) This process is documented in this Microsoft Knowledge Base article: http://support.microsoft.com/?id=950782. (SCCM 2007 Service Pack 1 will natively support these operating systems when it becomes available.)
SCCM2007 OSD组件使用WAIK来生成、管理和部署WIM镜像。SCCM2007安装WAIK 1.0版本。如果想使用SCCM2007部署VISTA SP1和Windows 2008，WAIK必须升级到1.1。相关文档参考微软知识库（KB）http://support.microsoft.com/?id=950782，SCCM2007 SP1将会原生支持这两个操作系统部署而不需要再行升级。

The first two steps in this process are very straight forward: uninstall WAIK 1.0, then install WAIK 1.1. The second two steps document a method of creating new WinPE 1.1 Boot Images and importing them into SCCM. The WinPE Boot Images need to be version 1.1 to support deploying Windows Vista SP1 and Windows Server 2008. If you are using the latest version of the Microsoft Deployment Toolkit 2008 with SCCM 2007 integration enabled (v4.1 released in March is the latest), you can use the menu option that MDT adds to the SCCM Boot Images node for creating new boot images and avoid step 3.
第一步，卸载原有的WAIK 1.0，安装WAIK 1.1
第二步，生成新的PE 1.1版引导镜像并导入SCCM——1.1版PE支持部署VIsta SP1和2008。如果你是用与SCCM 2007相整合的最新版本的MDT2008，MDT2008将在SCCM的Boot Images节点创建菜单选择，选择生成新的引导镜像，跳过第三步

However, if you are not using MDT and want to create new default SCCM boot images, the method documented in step 3 of KB 950782 is likely to give you about as much pleasure as a root canal. This method uses WBEMTest, a tool for testing WMI that is built into the OS. If you've used WBEMTest before, the experience is usually something you don't want to repeat. While it is very flexible for testing many WMI options, it is very tedious to use to execute a simple WMI method (as is needed to create new default SCCM boot images). So to alleviate this pain, I used the WMI Code Creator and the SCCM SDK to create a VBScript that turns the long mouse click tedium of WBEMTest into a few second operation.
如果你并没有使用MDT而又想创建新的默认SCCM引导镜像，那么KB950782中提到的第三步将是最好的选择。这种方法使用WBEMTest，一个测试操作系统WMI的工具。如果你以前使用过WBEMTest，那种经历你常常是不愿意再体验的。尽管他测试很多wmi选项时十分方便，但执行一个简单WMI方法十分枯燥无聊（因为需要生成新的SCCM引导镜像）。为了减轻这种痛苦，我常使用WMI编码生成器和SCCM SDK开发包来生成一个VBScript，将WBEMTest中冗长的鼠标点选转换为几秒中的操作。

To use this script, log on to the SCCM site server as an SCCM administrator. Create a folder that will hold the new boot images. If you are going to import the boot images from this folder, you may want to create it in the location when you keep your package source folders. (The folder from which the WinPE WIM file is imported becomes the boot image package data source.) Copy the ExportDefaultBootImages.vbs (listed below) to a folder on the server and edit the strExportFolder variable to point to the folder you just created. Then run then script from a command prompt with cscript.exe. When the script is finished you will have two sub folders, one containing an x86 boot image and one containing an x64 boot image. You can then either import the images as documented in step 4 of KB 950782 from these folders or move them to another location and import from there.
要使用这个教本，使用SCCM Adminstrator登陆SCCM Site服务器。建立一个文件夹，包含新的引导镜像。如果你想从这个文件夹导入引导镜像，你最好在你存放包的源文件的目录里创建它。（这个文件夹将变成引导镜像包的数据源）。拷贝ExportDefaultBootimages.vbs到服务器的一个文件夹里，并修改strExportFolder变量，指向你刚才创建的文件夹。使用命令行工具cscript.exe来执行脚本。当脚本执行完成，你将有两个子文件夹，一个包含x86的引导镜像，而另一个时x64的。你可以使用KB950782中的第四步来导入镜像，或者手动把他们移到其他地方并导入他们

ExportDefaultBootImages.vbs

' Windows Script Host Sample Script
' ------------------------------------------------------------------------
' Copyright (C) 2008
'
' You have a royalty-free right to use, modify, reproduce and distribute
' the Sample Application Files (and/or any modified version) in any way
' you find useful, provided that you agree that Microsoft and the author
' have no warranty, obligations or liability for any Sample Application
' Files.
' ------------------------------------------------------------------------
'This script replaces the procedure in step 3
'of this Microsoft Knowledge Base article:
'http://support.microsoft.com/?kbid=950782
strExportFolder = "E:\BootImages"
Set objFSO = CreateObject("Scripting.FileSystemObject")
'Export x86 boot image
strx86Folder = strExportFolder & "\Default_WAIK_1_1_x86"
If Not objFSO.FolderExists(strx86Folder) Then objFSO.CreateFolder(strx86Folder)
ExportBootImage "x86", strx86Folder & "\WAIK_1_1_boot_image_x86.wim", 1
'Export x64 boot image
strx64Folder = strExportFolder & "\Default_WAIK_1_1_x64"
If Not objFSO.FolderExists(strx64Folder) Then objFSO.CreateFolder(strx64Folder)
ExportBootImage "x64", strx64Folder & "\WAIK_1_1_boot_image_x64.wim", 1

Function GetSiteCode
GetSiteCode = ""
strComputer = "."
Set objWmiSmsNamespace = GetObject("winmgmts:\\" & strComputer & "\root\SMS")
Set objSmsProviderLoc = objWmiSmsNamespace.InstancesOf("SMS_ProviderLocation")
For Each location In objSmsProviderLoc
If location.ProviderForLocalSite = True Then
GetSiteCode = location.SiteCode
End If
Next
End Function

Sub ExportBootImage(strArchitecture, strExportImagePath, intImageIndex)
strComputer = "."
Set objWmiSmsSiteNamespace = GetObject("winmgmts:\\" & strComputer & "\root\SMS\site_" & GetSiteCode)
' Obtain an instance of the the class
Set objShare = objWmiSmsSiteNamespace.Get("SMS_BootImagePackage")
' Obtain an InParameters object specific
' to the method.
Set objInParam = objShare.Methods_("ExportDefaultBootImage").inParameters.SpawnInstance_()
' Add the input parameters.
objInParam.Properties_.Item("Architecture") = strArchitecture
objInParam.Properties_.Item("ExportImagePath") = strExportImagePath
objInParam.Properties_.Item("ImageIndex") = intImageIndex
' Execute the method and obtain the return status.
' The OutParameters object in objOutParams
' is created by the provider.
Set objOutParams = objWmiSmsSiteNamespace.ExecMethod("SMS_BootImagePackage", "ExportDefaultBootImage", objInParam)
' List OutParams
Wscript.Echo "Out Parameters for " & strArchitecture & " boot image : "
Wscript.echo "ReturnValue: " & objOutParams.ReturnValue
End Sub

相关资料：
How to replace Windows AIK version 1.0 with Windows AIK version 1.1 when you use System Center Configuration Manager 2007
http://support.microsoft.com/?id=950782
Automated Installation Kit (AIK) for Windows Vista SP1 and Windows Server 2008 (WAIK 1.1)
http://www.microsoft.com/downloads/details.aspx?familyid=94BB6E34-D890-4932-81A5-5B50C657DE08&displaylang=en
TechNet Magazine Utility Spotlight: WMI Code Creator
http://technet.microsoft.com/en-us/magazine/cc161034.aspx
System Center Configuration Manager 2007 Software Development Kit (SDK) v4.0
http://www.microsoft.com/downloads/details.aspx?FamilyId=064A995F-EF13-4200-81AD-E3AF6218EDCC&displaylang=en