unity 边缘检测shader简介（一）

边缘检测在游戏开发过程中有很多运用，包括模型外发光、卡通风格渲染的描边等，在Real-Time Rendering一书中介绍了几种边缘检测技术，主要包括表面角获取轮廓、过程几何获取轮廓、通过图像处理生成轮廓。

先介绍一下通过表面角获取轮廓，其原理如下图，模型上的点，越接近边缘，其视角与法线的夹角越大(接近90度)。



下面通过一个边缘发光的shader，具体了解一下这个原理。shader代码如下，这个shader只简单的包括了环境光和漫反射光。

Shader "Unlit/Rim"
{
Properties{
_Diffuse("Diffuse", Color) = (1, 1, 1, 1)
_RimColor("RimColor",Color) = (1,1,1,1)
_RimPow("RimPow",Range(1,10)) = 2
_RimIdentity("RimIdentity",Range(0,10))=3
}
SubShader{
Pass{
Tags{ "LightMode" = "ForwardBase" }

CGPROGRAM

#pragma vertex vert
#pragma fragment frag

#include "Lighting.cginc"

fixed4 _Diffuse;
fixed4 _RimColor;
float _RimPow;
float _RimIdentity;
struct a2v {
float4 vert : POSITION;
float3 normal : NORMAL;
};

struct v2f {
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float4 worldPos:TEXCOORD1;
};

v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vert);
o.worldNormal = mul((float3x3)unity_ObjectToWorld,v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vert);
return o;
}

fixed4 frag(v2f i) : SV_Target{
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));

fixed3 worldCamDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);

half rim = 1.0 - max(0,dot(worldCamDir, worldNormal));

fixed3 rimCol = _RimColor.rgb*pow(rim, _RimPow);

fixed3 color = ambient+ diffuse+rimCol*_RimIdentity;

return fixed4(color, 1.0);
}

ENDCG
}
}
FallBack "Diffuse"

}

像素着色器中，通过如下代码获取同一坐标系下的归一化的视角方向及法线方向：

fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldCamDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);

通过如下代码产生自放光，其中rim度量视角及法线的夹角大小，_RimPow可以控制边缘宽度，_RimIndentity控制自放光强度。

half rim = 1.0 - max(0,dot(worldCamDir, worldNormal));

fixed3 rimCol = _RimColor.rgb*pow(rim, _RimPow);

fixed3 color = ambient+ diffuse+rimCol*_RimIdentity;

效果如下：


ml