Win7使用批处理配置IP地址

一些场合常常需要把笔记本上的IP地址配置为某个静态值，一些场合又常常配置为自动获取IP，常常切换的话，手动输入这些IP地址十分麻烦。下面两个批处理脚本用于自动配置IP地址，使用管理员身份运行即可，笔者亲测可行。

配置为静态IP:

@echo off
echo 正在设置ip,子网,请稍候......
rem "本地连接"为网卡名称，可在网络连接中查询，如"本地连接"
netsh interface ip set address name="本地连接" source=static addr=192.168.56.137 mask=255.255.255.0  gateway=192.168.56.1 gwmetric=1
echo.
echo 正在设置DNS,请稍候.....
netsh int ip set dns name="本地连接" source=static addr=192.168.56.1
netsh int ip add dns name="本地连接" addr=8.8.8.8 index=2
echo 设置完毕!
ipconfig
pause
close

配置为自动IP:

@echo off
netsh interface ipv4 set address name="本地连接" source=dhcp
netsh interface ipv4 set dns name="本地连接" source=dhcp
echo ----
pause

附：自用脚本源码

@echo off
rem //设置变量
set NAME="无线网络连接"
rem //以下属性值可以根据需要更改
set ADDR=192.168.1.100
set MASK=255.255.255.0
set GATEWAY=192.168.1.1
set DNS1=8.8.8.8
set DNS2=8.8.8.8
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS
goto 0
:0
echo 当前可用操作有：
echo 1 设置为静态IP
echo 2 设置为动态IP
echo 3 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3

:1
echo 正在设置静态IP,请稍等…
rem //可以根据你的需要更改
echo IP地址 = %ADDR%
echo 掩码 = %MASK%
echo 网关 = %GATEWAY%
netsh interface ipv4 set address name=%NAME% source=static addr=%ADDR% mask=%MASK% gateway=%GATEWAY% gwmetric=0 >nul
echo 首选DNS = %DNS1%
netsh interface ipv4 set dns name=%NAME% source=static addr=%DNS1% register=PRIMARY >nul
echo 备用DNS = %DNS2%
netsh interface ipv4 add dns name=%NAME% addr=%DNS2% index=2 >nul
echo 静态IP已设置!
rem pause
goto 0

:2
echo 正在设置动态IP,请稍等…
echo 正在从DHCP自动获取IP地址…
netsh interface ip set address %NAME% dhcp
echo 正在从DHCP自动获取DNS地址…
netsh interface ip set dns %NAME% dhcp
echo 动态IP已设置!
rem pause
goto 0

:3
exit