WIN32汇编定时器的使用

// Generated by ResEdit 1.6.6
// Copyright (C) 2006-2015
// http://www.resedit.net #include <windows.h>
#include <commctrl.h>
#include <richedit.h>
#define IDI_ICON1                               1
#define IDI_ICON2                               2
#define IDD_DIALOG1                             103
#define IDC_SETICON                             100
#define IDC_COUNT                               102
//
// Dialog resources
//
LANGUAGE LANG_NEUTRAL, SUBLANG_NEUTRAL
IDD_DIALOG1 DIALOG 0, 0, 186, 95
STYLE DS_CENTER | DS_MODALFRAME | DS_SETFONT | WS_CAPTION | WS_VISIBLE | WS_POPUP | WS_SYSMENU
CAPTION "定时器例子"
FONT 9, "宋体"
{
LTEXT           "计数：", 101, 75, 30, 25, 9, SS_LEFT, WS_EX_LEFT
LTEXT           "", 102, 119, 28, 17, 26, SS_LEFT, WS_EX_LEFT
icon         "",100,23, 22, 38, 33, WS_EX_LEFT               //   就是这一句
}
//
// Icon resources
//
LANGUAGE LANG_NEUTRAL, SUBLANG_NEUTRAL
IDI_ICON1          ICON           "icon4.ico"

LANGUAGE LANG_NEUTRAL, SUBLANG_NEUTRAL
IDI_ICON2          ICON           "icon8.ico"

.386
.model flat,stdcall
option casemap:none
;-------------------------------------------------------------------
;include  文件定义
;-------------------------------------------------------------------
include         windows.inc
include         user32.inc
includelib      user32.lib
include         kernel32.inc
includelib      kernel32.lib
;-------------------------------------------------------------------
;等值定义
;-------------------------------------------------------------------
IDI_ICON1       equ       1
IDI_ICON2       equ       2
IDD_DIALOG1     equ       103
IDC_SETICON     equ       100
IDC_COUNT       equ       102
ID_TIMER1       equ       1
ID_TIMER2       equ       2
;-------------------------------------------------------------------
;数据段
;-------------------------------------------------------------------
.data?
hInstance       dd        ?
hWinMain        dd        ?
dwCount         dd        ?
idTimer         dd        ?
;-------------------------------------------------------------------
;代码段
;-------------------------------------------------------------------
.code
;-------------------------------------------------------------------
;定时器过程
;-------------------------------------------------------------------
_ProcTimer      proc      _hwnd,uMsg,_idEvent,_dwTime

pushad
invoke    GetDlgItemInt,hWinMain,IDC_COUNT,NULL,FALSE
inc       eax
invoke    SetDlgItemInt,hWinMain,IDC_COUNT,eax,FALSE
popad
ret

_ProcTimer endp
;-------------------------------------------------------------------
;窗口过程
;-------------------------------------------------------------------
_ProcDlgMain    proc      uses ebx edi esi,hWnd,uMsg,wParam,lParam

mov       eax,uMsg
.if       eax ==  WM_TIMER
mov     eax,wParam
.if      eax ==  ID_TIMER1
inc     dwCount                                 ；此处很有意思
mov     eax,dwCount
and     eax,1
inc     eax
invoke  LoadIcon,hInstance,eax
invoke  SendDlgItemMessage,hWnd,IDC_SETICON,STM_SETIMAGE,IMAGE_ICON,eax
.elseif   eax ==  ID_TIMER2
invoke  MessageBeep,-1
.endif
.elseif eax ==  WM_INITDIALOG
push    hWnd                                             ；注意此处的储存变量的方式
pop     hWinMain
invoke  SetTimer,hWnd,ID_TIMER1,250,NULL
invoke  SetTimer,hWnd,ID_TIMER2,2000,NULL
invoke  SetTimer,NULL,NULL,1000,addr _ProcTimer
mov     idTimer,eax
;-------------------------------------------------------------------
.elseif eax ==  WM_CLOSE
invoke  KillTimer,hWnd,ID_TIMER1
invoke  KillTimer,hWnd,ID_TIMER2
invoke  KillTimer,hWnd,idTimer
invoke  EndDialog,hWnd,NULL
;-------------------------------------------------------------------
.else
mov eax,FALSE
ret
.endif
mov     eax,TRUE
ret

_ProcDlgMain endp
;-------------------------------------------------------------------
start:
invoke GetModuleHandle,NULL
mov    hInstance,eax
invoke DialogBoxParam,hInstance,IDD_DIALOG1,NULL,offset _ProcDlgMain,NULL
invoke ExitProcess,NULL
;-------------------------------------------------------------------
end    start

API函数：
SetTimer()
功能：
一种API函数，位于user32.dll中。你想每隔一段时间执行一件事的的时候，你可以使用它。 使用定时器的方法比较简单，通常告诉Windows一个时间间隔，然后Windows以此时间间隔周期性触发程序。通常有两种方法来实现:发送WM_TIMER消息和调用应用程序定义的回调函数。不需要指定定时器时，可以调用对应的KillTimer函数销毁指定的时钟。
原型参数：
UINT_PTR SetTimer(

HWND hWnd, // 窗口句柄

UINT_PTR nIDEvent, // 定时器ID，多个定时器时，可以通过该ID判断是哪个定时器

UINT nElapse, // 时间间隔,单位为毫秒

TIMERPROC lpTimerFunc // 回调函数

);

返回值：

类型:UINT_PTR

如果函数成功,hWnd参数为0,则返回新建立的时钟编号,可以把这个时钟编号传递给KillTimer来销毁时钟.

如果函数成功,hWnd参数为非0,则返回一个非零的整数,可以把这个非零的整数传递给KillTimer来销毁时钟.

如果函数失败,返回值是零.

KillTimer()

功能：

该函数移除先前用SetTimer设置的定时器。在定时器使用完毕后移除定时器时使用。

原型：

KillTimer(

HWND hWnd

UINT_PTR nIDEvent

)

参数：

hWnd:与定时器相关联的窗口句柄

nIDEvent: 传递给SetTimer的定时器ID值。

返回值：

如果函数成功,返回一个非0值,

如果失败,返回值为0

MessageBeep（）

功能：

用来播放一个波形声音。

原型：

BOOL MessageBeep(

UINT uType //根据不同的类型来定

);

参数;
uType

Specifies the sound type, as identified by an entry in the [sounds] section of the registry. It is one of the following values.

Value Description （数值描述）：

0xFFFFFFFF SystemDefault （从机器的扬声器中发出蜂鸣声）

MB_ICONASTERISK SystemAsterisk （播放由SystemAsterisk定义的声音）

MB_ICONEXCLAMATION SystemExclamation （播放由SystemExclamation定义的声音）

MB_ICONHAND SystemHand （播放由SystemHand定义的声音）

MB_ICONQUESTION SystemQuestion （播放由SystemQuestion定义的声音）

MB_OK SystemDefault （播放由SystemDefault定义的声音）

返回值：

.Nonzero indicates success. (非零表示成功)

2.Zero indicates failure. （零表示不成功）

结束。