80x86 汇编语言：键控顺序显示不同符号序列

;80x86汇编语言

;程序一开始循环显示0、1...9，按空格键后循环显示A、B...Z，再按空格键显示数字，按其它结束。

;题目链接：http://zhidao.baidu.com/question/2202638368467673828.html

;做而论道编程如下：(2014-06-09 18:48 提问者采纳)

;=========================================================
ASSUME  CS:CC, DS:QW
;-------------------------
QW SEGMENT
    XX  DB  '0'
    ZZ  DB  1
QW  ENDS
;-------------------------
CC SEGMENT

START:
    MOV  AX, QW
    MOV  DS, AX
;-------------------
M_LOP:
    CALL OUT_CHR

    MOV  AH, 1     ;键盘状态
    INT  16H       ;读
    JZ   WT   
    MOV  AH, 0     ;键盘内容
    INT  16H       ;读
    CMP  AL, ' '
    JNE  EXIT

    INC  ZZ
    TEST ZZ, 1
    JNZ  O_09
    MOV  XX, 'A'
    JMP  WT
O_09:
    MOV  XX, '0'

WT: MOV  CX, 3000  ;延时
WT0:MOV  DX, 0
WT1:DEC  DX
    CMP  DX, 0
    JNZ  WT1
    LOOP WT0       ;延时结束

    JMP  M_LOP
;-------------------
EXIT:
    MOV  AH, 4CH
    INT  21H
;-------------------------
OUT_CHR:
    MOV  AH, 2
    MOV  DL, XX
    INT  21H
    MOV  DL, ' '
    INT  21H

    INC  XX
    CMP  XX, '9' + 1
    JNZ  NEXT1
    MOV  XX, '0'
    RET
NEXT1:
    CMP  XX, 'Z' + 1
    JNZ  NEXT2
    MOV  XX, 'A'
NEXT2:
    RET
;-------------------------
CC ENDS
    END  START
;=========================================================