【酷Q插件制作】教大家做一个简单的签到插件

酷Q插件已经有很多了，社区分享一大堆，不过还是自己写才有乐趣，哈哈。
不得不吐槽一下，酷Q竟然不更新了，出了个酷Q pro，还收费！！诶。
不过这也影响不了咱写插件的心情，今天教大家写一个酷Q签到插件，虽然很简单，但是基本原理已经体现出来了，大家参考着就可以写出更好的了。
推荐大家浏览前几篇酷Q的插件编写教程文章。

酷Q机器人，QQ机器人使用教程

【酷Q插件制作】教你编写第一个酷Q插件

酷Q签到插件插件

插件示例

.版本 2
.支持库 internet

.程序集 程序集1

.子程序 _启动子程序, 整数型, , 请在本子程序中放置易模块初始化代码

_临时子程序 ()  ' 在初始化代码执行完毕后调用测试代码
返回 (0)  ' 可以根据您的需要返回任意数值

.子程序 _临时子程序

' 本名称子程序用作测试程序用，仅在开发及调试环境中有效，编译发布程序前将被系统自动清空，请将所有用作测试的临时代码放在本子程序中。 ***注意不要修改本子程序的名称、参数及返回值类型。
info ()

.子程序 info, 文本型, 公开
.局部变量 返回消息, 文本型

' 返回一个字符串，用于告知插件信息，十个信息用换行分割，不可多不可少
返回消息 ＝ 返回消息 ＋ “公会系统” ＋ #换行符  ' 第1个是插件名称，必填
返回消息 ＝ 返回消息 ＋ “1.0版” ＋ #换行符  ' 第2个是版本号，必填
返回消息 ＝ 返回消息 ＋ “擦擦擦” ＋ #换行符  ' 第3个是作者，必填
返回消息 ＝ 返回消息 ＋ “签到” ＋ #换行符  ' 第4个是用途，在机器人输出插件列表时显示
返回消息 ＝ 返回消息 ＋ “@签到” ＋ #换行符  ' 第5个是格式左，选填，插件接收到的数据将从这个信息开始
返回消息 ＝ 返回消息 ＋ “” ＋ #换行符  ' 第6个是格式名称，选填，将在输出插件列表时显示
返回消息 ＝ 返回消息 ＋ “” ＋ #换行符  ' 第7个是格式右，选填，插件将接收到格式左到格式右之间的内容
' 只要【格式左】为空，则用户发送的每个消息插件都会完整收到(不支持3.1.25之前的版本)
' (如格式左为“”，格式名称为“人品”,如格式右为“”,用户发送“哈哈，看看今天人品咯~！”，插件会收到“哈哈，看看今天人品咯~！”)

' 如果【格式名称】与【格式右】皆空，则只要含有【格式左】的消息插件就会收到消息(收到的内容为空)

' 如果仅【格式右】空，则返回用户发送消息的【格式左】之后的内容
' (如格式左为“@人品 ”，格式名称为“名字 ”，用户发送“@人品 酷Q”，插件会收到“酷Q”)

' 如果【格式左】、【格式名称】、【格式右】都填写，则返回用户发送消息的格式左到格式右之间的内容
' (如格式左为“@人品[”，格式名称为“名字 ”,如格式右为“]”,用户发送“@人品[酷Q]”，插件会收到“酷Q”)

' 作者.离骚，机器人插件研发群 224510783

返回消息 ＝ 返回消息 ＋ “plugmain” ＋ #换行符  ' 第8个是调用名，必填，当要调用插件时调用的子程序名
返回消息 ＝ 返回消息 ＋ “1” ＋ #换行符  ' 第9个是类型，必填，填1为在全部功能列表中显示，填2为不在全部功能列表中显示
返回消息 ＝ 返回消息 ＋ “假” ＋ #换行符  ' 第10个是是否获取登录用户cookies，必填，填真将可以得到用户Cookies(需用户授权)，填假则不得到
输出调试文本 (shuchu (“326794739”, “235891629”))
返回 (返回消息)

.子程序 plugmain, 文本型, 公开, 准备五个参数，均为文本型
.参数 返回数据, 文本型, , 插件收到的数据，由于本插件【格式名称】与【格式右】都为空，所以返回数据始终为空
.参数 消息类型, 文本型, , 类型（1为好友消息 2为群消息 3为临时消息）
.参数 发送者群号, 文本型, , 群号（群消息为群号，其他为空）
.参数 发送者Q号, 文本型, , 发送者QQ
.参数 Cookies, 文本型, , Cookies(需要返回Cookies，否则返回空)[无论是否需要请保留此参数]
.局部变量 欲返回, 文本型

欲返回 ＝ “本插件仅限群内使用！” ＋ 随即表情 ()
.如果真 (到整数 (消息类型) ＝ 2)
欲返回 ＝ shuchu (发送者Q号, 发送者群号)
.如果真结束
返回 (欲返回)

.子程序 shuchu, 文本型
.参数 发送者Q号, 文本型
.参数 发送者群号, 文本型
.局部变量 输出值, 文本型
.局部变量 temp, 文本型

' 发送者群号 ＝ 删全部空 (发送者群号)
' 发送者群号 ＝ 子文本替换 (发送者群号, #换行符, “”, , , 真)
' 发送者群号 ＝ 子文本替换 (发送者群号, “+”, “”, , , 真)
配置目录 ＝ 取运行目录 () ＋ “\config\qiandao” ＋ 发送者群号 ＋ “User.ini”
temp ＝ 读配置项 (配置目录, 发送者Q号, “是否加入”, )
.如果 (temp ≠ “是”)

写个人配置 (到文本 (1), 发送者Q号, “签到次数”)
写个人配置 (时间格式化 (), 发送者Q号, “签到时间”)
写个人配置 (“是”, 发送者Q号, “是否加入”)
输出值 ＝ 获取qq昵称 (发送者Q号) ＋ “-签到成功，您是第一次签到！”

.否则

' 开始签到
' 判断今日是否签到
.如果 (取个人配置 (发送者Q号, “签到时间”) ＝ 时间格式化 ())
' 今日已签  失败
输出值 ＝ 获取qq昵称 (发送者Q号) ＋ “你今天已经签过到了！”

.否则

' 可以签到

写个人配置 (到文本 (到整数 (取个人配置 (发送者Q号, “签到次数”)) ＋ 1), 发送者Q号, “签到次数”)
写个人配置 (时间格式化 (), 发送者Q号, “签到时间”)
输出值 ＝ 获取qq昵称 (发送者Q号) ＋ “-签到成功，共签到” ＋ 取个人配置 (发送者Q号, “签到次数”) ＋ “次！”

.如果结束

.如果结束
返回 (输出值 ＋ 随即表情 ())

.子程序 写个人配置, 逻辑型, 公开
.参数 值, 文本型
.参数 发送者q号, 文本型
.参数 配置名, 文本型

返回 (写配置项 (配置目录, 发送者q号, 配置名, 值))

.子程序 取个人配置, 文本型, 公开
.参数 发送者q号, 文本型
.参数 配置名, 文本型

返回 (读配置项 (配置目录, 发送者q号, 配置名, ))

.子程序 随即表情, 文本型, 公开

置随机数种子 ()
返回 (“[bq” ＋ 到文本 (取随机数 (0, 134)) ＋ “]”)

.子程序 时间格式化, 文本型, 公开, 流绪微梦~邪少制作。。。。。QQ群：211973761
.局部变量 日期, 文本型

日期 ＝ 时间到文本 (取现行时间 (), #日期部分)
日期 ＝ 子文本替换 (日期, “年”, “.”, , , 真)
日期 ＝ 子文本替换 (日期, “月”, “.”, , , 真)
日期 ＝ 子文本替换 (日期, “日”, “”, , , 真)
返回 (日期)

.子程序 取文本之间, 文本型, 公开, 流绪微梦~邪少制作。。。。。QQ群：211973761
.参数 被搜寻的文本, 文本型
.参数 开始文本, 文本型
.参数 结束文本, 文本型
.局部变量 文本长度, 整数型
.局部变量 开始位置, 整数型
.局部变量 取出长度, 整数型

文本长度 ＝ 取文本长度 (开始文本)
开始位置 ＝ 寻找文本 (被搜寻的文本, 开始文本, , 真) ＋ 文本长度
取出长度 ＝ 寻找文本 (被搜寻的文本, 结束文本, 开始位置, 真) － 开始位置
返回 (取文本中间 (被搜寻的文本, 开始位置, 取出长度))

.子程序 获取qq昵称, 文本型, 公开, 流绪微梦~邪少制作。。。。。QQ群：211973761
.参数 QQ号, 文本型
.局部变量 QQ昵称, 文本型
.局部变量 temp, 文本型

temp ＝ 读配置项 (配置目录, QQ号, “QQ昵称”, )
.如果 (temp ＝ “”)
QQ昵称 ＝ 到文本 (HTTP读文件 (“http://r.qzone.qq.com/fcg-bin/cgi_get_score.fcg?mask=7&uins=” ＋ QQ号))
QQ昵称 ＝ 取文本之间 (QQ昵称, “,” ＋ #引号, #引号 ＋ “,”)

.否则

QQ昵称 ＝ temp
.如果结束

输出调试文本 (QQ昵称)
返回 (QQ昵称)

.子程序 输出值

View Code