怎么监视跟踪一个进程（Process）中的MS Unit Test DLL的详细性能（performance）【asp.net C#】

Sample

This tutorial will show how to instrument a unit test DLL for performance profiling. Visual Studio will allow you to do performance profiling on individual tests (i.e. functions) in a test suite. This can be done in the user interface (i.e. UI or IDE). However if you have a unit test DLL that contains lots of unit tests or test methods, it’s apparently not possible to do performance profiling in the IDE.

Here was my original question:

Question on MSDN forums

Preparation

Build the code that you will be testing. In my case it was the following DLL’s (Assuming a common root folder)

DLL name	Description
..\ManagedAPI\Win32\Debug\UnderstandWrapper.ManagedAPI.dl	The DLL with the code I wanted to test
..\UnitTest\bin\x86\Debug\UnitTest.dll	This DLL contains my unit tests

Then just to play it safe, run all the unit tests (This can be done in the IDE) in UnitTest.dll. It pays to be paranoid like this since if you want to detect bugs early and swiftly.

Now the strategy for profiling an entire DLL is to:

Instrument the DLL. This means to inject performance related commands into the code. Don’t worry it’s perfectly safe.

Turn on performance profiling via a global command.

Run your unit tests. Here is where the real work gets done.

Turn off performance profiling via a global command. (A results file gets saved somewhere).

Un-Instrument the DLL. This means restoring it to it’s original state. (i.e. Don’t ship a DLL with performance profiling enabled).

Instrument the Binaries

I instrument my DLL’s using the following batch script called: Instrument_ON.bat

@echo off

@echo Instrumenting Binary

set VS90TEAMTOOLS="%VS90COMNTOOLS%..\..\Team Tools\Performance Tools\"

%VS90TEAMTOOLS%\VSInstr.exe ..\ManagedAPI\Win32\Debug\UnderstandWrapper.ManagedAPI.dll

%VS90TEAMTOOLS%\VSInstr.exe ..\UnitTest\bin\x86\Debug\UnitTest.dll

pause

@echo on

The results of instrumenting it looks like this:

Turn on Monitor

I then turn on performance profiling using the following batch script called: Performance_ON.bat

@echo off

@echo Turning ON performance coverage session recorder

set VS90TEAMTOOLS="%VS90COMNTOOLS%..\..\Team Tools\Performance Tools"

%VS90TEAMTOOLS%\VsPerfCmd /start:trace /output:ManagedAPI.vsp

pause

@echo on

The results of this batch scripts looks like this:


The results of this script is it starts another process that will monitor any application that happens to be instrumented with performance profiling, or code coverage profiling. In our case it started a process called VsPerfMon.exe:

Run Unit Tests

I then run all the unit tests in my DLL using another batch script. Now I have two build configurations (debug and release) so I have two batch scripts to run those: Run_Tests_Debug.bat and Run_Tests_Release.bat. Here is one of them:

@echo off

color 16

@echo Running Unit Tests

call "C:\Program Files (x86)\Microsoft Visual Studio 9.0\Team Tools\Performance Tools\VsPerfCLREnv" /traceon

call "C:\Program Files (x86)\Microsoft Visual Studio 9.0\VC\vcvarsall.bat";

mstest /testcontainer:%CD%\UnitTest\bin\x86\Debug\UnitTest.dll > results.txt

pause

@echo on

Notice there the actual call to mstest.exe is what runs the unit tests. Notice that I piped the results of running the actual unit tests into a text file (i.e. results.txt). I did this because it gives me a more permanent record of how my unit tests did.

The mstest.exe file resides on my computer at:

"C:\Program Files (x86)\Microsoft Visual Studio 9.0\Common7\IDE\MSTest.exe"

The output, to the console window, of this script on my looks like the following:


Noticed I redirected the standard output (standard out) to a text file. The results.txt file looks like this:


Feels good to see all the unit tests pass. But now I have to save out the results of the performance profiling. And to do this, I now have to turn off the VsPerfMon.exe process that is running, and was running when I ran my unit tests.

Turn off Monitor

I have a batch script that turns off monitoring and saves out a results file containing all the profiling goodness. Performance_OFF.bat

@echo off

@echo Turning off performance coverage session recorder

set VS90TEAMTOOLS="%VS90COMNTOOLS%..\..\Team Tools\Performance Tools"

%VS90TEAMTOOLS%\VSPerfCmd /shutdown

pause

@echo on

The results of this batch script looks like this:



Now a new file is saved out to my computer:

F:\CodePlex\UnderstandAPI\Managed\Performance\ManagedAPI.vsp

Notice the name: ManagedAPI.vsp. This is the same name I passed in when I turned on the Performance Monitor. Remember this?


Now at this point, you can do two things:

Examine your performance results. This is done by double clicking the ManagedAPI.vsp file. This will just launch visual studio, and display the results of your tests:

Or Uninstrument your DLL’s. It’s never a good idea to ship DLL’s with instrumentation in them.

Un-Instrument the Binaries

I have a script that does this for me: Instrument_OFF.bat

@echo off

@echo Removing Instrumented Files

pushd ..\ManagedAPI\Win32\Debug

if exist UnderstandWrapper.ManagedAPI.instr.pdb (

del UnderstandWrapper.ManagedAPI.instr.pdb

del UnderstandWrapper.ManagedAPI.dll

rename UnderstandWrapper.ManagedAPI.dll.orig UnderstandWrapper.ManagedAPI.dll

)

popd

pushd ..\UnitTest\bin\x86\Debug

if exist UnitTest.instr.pdb (

del UnitTest.instr.pdb

del UnitTest.dll

rename UnitTest.dll.orig UnitTest.dll

)

popd

pause

@echo on

When I run this, I get the following results in the command window:


However, sometimes I do this only after I reviewed my performance results. Since the performance results display in visual studio may be dependent on the instrumented binaries to properly display its data.

View Results

Now that you have your .vsp file it is time to open it. The file ManagedAPI.vsp shows the following in visual studio:



From there you can analyze the results and find your performance bottlenecks.