SQL语句创建计划

一、创建作业

USE msdb ;
GO
--第1步：常规
EXEC sp_add_job @job_name = '作业名字'

--第2步：步骤（执行存储过程,Sql语句）
EXEC sp_add_jobstep @job_name = '作业名字',
@step_name = '步骤名子',
@subsystem = 'TSQL',
@command = 'EXEC 数据库名称.dbo.存储过程名',
@retry_attempts = 5, --重试次数
@retry_interval = 5 --重试间隔

--第3步：计划（计划执行时间）
EXEC sp_add_jobschedule @job_name = '作业名字',
@name = '作业调度名字',
@freq_type = 4, -- 每天
@freq_interval = 26, --间隔
@active_start_time = 10000 --开始时间

--第4步：附加计划
EXEC sp_attach_schedule
@job_name = '作业名字', --计划的作业的名称
@schedule_name = '作业调度名字' ; --作业设置的计划的名称
GO

--第5步：作业的目标服务器
EXEC dbo.sp_add_jobserver
@job_name = '作业名字', --作业的名称
@server_name = N'(local)' ; --该作业的目标服务器的名称
GO

常见问题：

SQLServerAgent 当前未运行，因此无法将此操作通知它。



右键启动

二、计划模板定义

--调度模板定义

--/*--日调度

EXEC msdb..sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',

    @freq_type=4,                --每天

    @freq_interval=1,            --指定每多少天发生一次,这里是1天.

    @freq_subday_type=0x8,       --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

    @freq_subday_interval=1,     --重复周期数,这里每小时执行一次

    @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

    @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

    @active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

    @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/

 

--/*--周调度

EXEC msdb.dbo.sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',  

    @freq_type = 8,              --每周

    @freq_recurrence_factor = 1, --每多少周执行一次,这里是每周

    @freq_interval = 62,         --在星期几执行,由POWER(2,N)表示,N的值为0~6,代表星期日~星期六,如果指定两个,则将值相加,例如,值为65表示在星期天和星期日执行(POWER(2,0)+POWER(2,6))

    @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

    @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

    @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

    @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

    @active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

    @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/

 

--/*--月调度(每X个月的每月几号)

EXEC msdb.dbo.sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',  

    @freq_type = 16,             --每月

    @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月

    @freq_interval = 2,          --在执行月的第几天执行,这里是第2天

    @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

    @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

    @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

    @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

    @active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

    @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/

 

--/*--月调度(每X个月的相对时间)

EXEC msdb.dbo.sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',  

    @freq_type = 32,             --每月

    @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月

    @freq_interval = 9,          --在当月的那个时间执行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末

    @freq_relative_interval = 1, --在第几个相对时间执行,允许的值为1,2,4,8代表第1~4个相对时间,16表示最后一个相对时间

    @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

    @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

    @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

    @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

    @active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

    @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/

 

--/*--在特定时候执行的作业调度

EXEC msdb.dbo.sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',  

    @freq_type = 64     --64=在SQLServerAgent 服务启动时运行,128=计算机空闲时运行

--*/

 

--/*--只执行一次的作业调度

EXEC msdb..sp_add_jobschedule

    @job_id = @jobid,

    @name = N'调度名称',

    @freq_type=1,                --仅执行一次

    @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

    @active_start_time = 00000   --作业执行的开始时间,格式为HHMMSS

--*/

转载：

USE msdb ;
GO
EXEC dbo.sp_add_job
@job_name = 'SQL_EmailOne1', --作业的名称
@enabled = 1, --指示添加的作业的状态(默认值为 1（启用）)
@description = 'Testing', --作业的说明
@owner_login_name = 'sa', --拥有作业的登录名
@notify_level_eventlog = 2, --0 从不 1 成功后 2（默认值）失败后 3 始终
@notify_level_email = 2, --默认值为 0，指示从不发送
@notify_level_netsend = 2, --默认值为 0，指示从不发送
@notify_level_page = 2, --默认值为 0，指示从不发送
@category_id=3, --作业的类别ID
@delete_level = 0 ; --默认值为0，不删除，用于指示何时删除作业
GO

USE msdb ;
GO
EXEC sp_add_jobstep
@job_name = 'SQL_EmailOne1', --步骤的作业的名称
@step_name = 'SQL_Emailone2', --步骤的名称
@server='svr2',--服务器名称
@database_name='testdb',--数据库名
@subsystem = 'TSQL', --Transact-SQL 语句\制表符 --CHAR(9) 换行符 CHAR(10) 回车 CHAR(13)
@command ='use orbitx declare @cnt int select @cnt=count( *) from sqlemail if @cnt>3 begin use msdb EXEC sp_send_dbmail @profile_name = ''two'',@recipients = ''xd@or.com'',@subject = ''邮件测试xdd'',@body = ''邮件测试成功xdd!'' end',
@retry_attempts = 2,--该步骤失败时的重试次数
@retry_interval = 0.05 ; --两次重试之间的间隔时间（分钟）
GO
USE msdb ;
GO
EXEC sp_add_schedule
@schedule_name = 'SQL_Emailone2' ,--计划的名称
@freq_type = 4 , --指示作业执行时间的值 1为一次，4为每天（1,8,16,32等参考帮助文档）值为2的次方
@freq_interval = 1,--作业执行的天数 说明同上
@freq_subday_type=0x4,
@freq_subday_interval=1,
@active_start_time = 010000 ;--数据类型为 int，默认值为 000000，指示 24 小时制的上午 12:00:00，并且必须使用 HHMMSS 的格式输入
GO
EXEC sp_attach_schedule
@job_name = 'SQL_EmailOne1', --计划的作业的名称
@schedule_name = 'SQL_Emailone2' ; --作业设置的计划的名称
GO

USE msdb ;
GO
EXEC dbo.sp_add_jobserver
@job_name = 'SQL_EmailOne1', --作业的名称
@server_name = 'svr' ; --该作业的目标服务器的名称
GO