WINRAR实现自动备份

WINRAR实现自动备份

一、文件方案：

1、制作配置文件

启动“资源管理器”，进入D:\Work文件夹。选中并右击所有文件，选择“WinRAR→添加到压缩包”，打开“压缩包名称和参数”窗口，单击“备份”标签，勾选“按掩码产生压缩文件名”复选框。接着单击“常规”标签。并单击“浏览”按钮，把文件保存到E:\bak文件夹下。 接着，单击“配置”按钮，选择“保存当前配置为新配置”，在“配置名称”中输入备份方案名，如“备份Work文件内容”，同时选中“保存档案文件名”“立即执行”和“保存选定文件名”及“在桌面创建快捷方式”前的复选框。单击“确定”按钮返回“保存档案文件名和参数”窗口，按下“确定”按钮备份文件。

2、定时备份

点击“开始→设置→控制面板→任务计划”。接着，把桌面上的“备份Work文件内容”快捷方式拖放到“任务计划”窗口。然后双击“备份Work文件内容”图标，设置其属性。 单击“日程安排”标签，单击“任务计划”下拉列表框，从中选择“每天”，而“开始时间”设置为自己的时间。 通过上述设置后，到了你设置的时间，电脑就会自动备份D:\Work下的所有所有文件到E:\bak文件夹下，且会按备份的日期和时间作为文件名，如work20130306141726.rar、work20130306151826.rar等。

二、脚本方案《可做差异备份哦》：

1、先建立要备份的档案清单档(MyDocument.lst，一般建立在备份后文件放置的文件夹E:\bak下)：

　//注解，可以写上你备份的文件

　D:\work

2、建立排除备份档案清单(MyDocument.nlst)：

　//注解

　*.JPG //所有.JPG档

　D:\work\Thumbs.db

※本档案不一定要存在，但如果有的话，档案名必需要跟lst一样。

3、制作如下BAT脚本：

@Echo OFF

:Menu

cls

Title [Winrar 备份批次程序]

@mode con cols=100 lines=32

color F0

echo.

echo.╭──────────╮

echo.│ │

echo.│WinRAR 备份批次程序│

echo.│ │

echo.╰──────────╯

echo.

SET Choice=

SET /P Choice=备份方式(0-完整,1-于几日内异动,2-于何日后异动):

IF /I '%Choice%'=='' GOTO Menu

IF /I %Choice%==0 GOTO Backup

IF /I %Choice%==1 GOTO byDiffDay

IF /I %Choice%==2 GOTO byDateAfter

:byDiffDay

echo.

echo 选择：1-于几日内异动 Ex.10

SET Choice=

SET /P Choice=差异备份日数(预设0表完整备份):

IF /I '%Choice%'=='' SET Choice=0

IF NOT %Choice%==0 SET Choice=-tn%Choice%d

GOTO Backup

:byDateAfter

echo.

echo 选择：2-于何日后异动 Ex.2000-01-01

SET Choice=

SET /P Choice=起始日期(格式:YYYYMMDD,预设0表完整备份):

IF /I '%Choice%'=='' SET Choice=0

IF NOT %Choice%==0 SET Choice=-TA%Choice%

:Backup

IF /I %Choice%==0 echo 开始进行完整备份.....

IF /I %Choice%==0 SET Choice=

IF not "%1"=="" (

SET FileList=%1

) ELSE (

SET FileList=*.lst

)

for %%f in (%FileList%) do (

IF EXIST %%~nf.nlst (

echo 找到 "%%f" Winrar压缩清单（含排除清单 "%%~nf.nlst" ），并开始压缩...

"%ProgramFiles%\WinRAR\WinRAR.exe" a -S -v2000M -M5 -RR -TK -ED -EP1 -R -INUL -IBCK -Y %Choice% -z%%f %%~nf @%%f
-x@%%~nf.nlst

) ELSE (

echo 找到指定 "%%f" Winrar压缩清单，并开始压缩...

"%ProgramFiles%\WinRAR\WinRAR.exe" a -S -v2000M -M5 -RR -TK -ED -EP1 -R -INUL -IBCK -Y %Choice% -z%%f %%~nf @%%f

)

)

echo 备份日期：%date% ,备份清单：%FileList% ,指定参数：%Choice% >>BackupList.Log

SET Choice=

SET FileList=

4、将 .lst .nlst .BAT 放在同一目录，.lst可以有多个

5、建立计划备份任务（同第一种方案）

附：

WinRAR 使用参数說明:

-S - 建立结实压缩

-V<n>[k|b|f|m|M|g|G] - 建立分割档案

-M<n> - 设定压缩方法(0-5,5-最佳)

-RR
- 加入资料复原记录

-TK - 保留原始压缩档时间

-ED - 不要加入空资料夹

-EP1 - 排除档案根据的资料夹

-R - 巡回子资料夹

-Z<档案> - 读取档案的压缩档注解

-x<档案> - 排除的档案清单

-INUL - 停用错误讯息

-IBCK - 在背景执行 WinRAR

-Y - 所有问题的预设值为「是」

-TN - 处理比指定时间还新的档案[<n日>d][<n时>h][<n分>m][<n秒>s]

-TA - 处理指定日期之后修改的档案,日期字串的格式是 YYYYMMDDHHMMSS