Win7开启WiFi，实现共享上网

      经常手机流量不够用，而电脑确能上网，上没有路由的情况下，如何能够让手机也共享上网呢。答案很简单，开启Wifi的Wifi功能即可。

       1、开启Win7虚拟无线网卡，并配置好相关信息。

       2、将电脑本地的网卡设置共享即可。

       为了操作简单，将开启虚拟Wifi的操作写了个脚本。

@echo off
title win7开启wifi热点工具 by：HelloWorld天真浪子
MODE con: COLS=55 LINES=25
color 0a
echo.
echo ★声明★
echo.
echo 本工具只在win7系统下进行过测试可用
echo XP系统不可用，请谅解
echo 本工具纯cmd命令编写，无毒，360若阻止请选择允许
echo.
echo 作者：HelloWorld天真浪子 ver：1.0
echo.
pause
echo.
echo 正在检测当前网卡是否支持wifi热点...
netsh wlan show drivers > c:\netsh.txt
echo.
findstr "支持的承载网络" c:\netsh.txt
::查找匹配"支持的承载网络"关键字的行并显示出来
echo.
echo 如果显示结果为“是”，网卡可以开启wifi热点
echo.
del c:\netsh.txt >nul
echo 继续y，退出n
echo.
set /p x= 请输入:
if /i "%x%"=="y" goto caidan
if /i "%x%"=="n" exit

:caidan
color 0a
cls
echo.
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 请选择要进行的操作，然后按回车
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo.
echo 首先确认你的网卡支持wifi热点
echo 否则本工具无法为你开启wifi热点
echo 其次确认你的笔记本已经正常连接Internet网络
echo.
echo PS：已经创建过wifi热点，可选第二项直接开启
echo.
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo.
echo 1、创建wifi热点
echo.
echo 2、开启wifi热点
echo.
echo 3、关闭wifi热点
echo.
echo 4、退出
echo.
echo.
set /p xz= 请选择:
if /i "%xz%"=="1" goto no1
if /i "%xz%"=="2" goto no2
if /i "%xz%"=="3" goto no3
if /i "%xz%"=="4" exit
if /i %xz% GTR "4" goto error
if /i %xz% LSS "1" goto error

:error
color 0c
cls
echo 输入错误，请按任意键返回菜单重新输入！
pause>nul & goto caidan

:no1
color 0a
cls
echo.
sc config MpsSvc start= demand >nul
net start MpsSvc >nul
netsh wlan set hostednetwork mode=allow >nul
cls
echo.
echo 请按以下步骤设置网卡
echo.
echo 1、打开“网络连接”
echo 2、右键单击已经连接到Internet的网络连接
echo 3、选择“属性”→“共享”，所有选项打勾
echo 4、成功后，设置“共享”的网卡会显示“共享的”字样
echo.
echo 是否需要为您自动打开“网络连接”？（y是，n否）
echo.
set /p yn= 请输入:
if /i "%yn%"=="y" start explorer.exe ::{7007ACC7-3202-11D1-AAD2-00805FC1270E} >nul & goto wifi
if /i "%yn%"=="n" goto wifi

:wifi
color 0a
echo.
echo 确认你已经对网卡设置完毕，按回车键继续...
pause >nul
cls
echo.
set /p ssid= 输入wifi热点名称（英文稳定）:
set /p passwd= 输入连接wifi密码（八位以上有效）:
netsh wlan set hostednetwork ssid=%ssid% key=%passwd% >nul
goto no2

:no2
netsh wlan start hostednetwork >nul
echo wifi热点已经开启，可以使用...
pause
goto caidan

:no3
netsh wlan stop hostednetwork >nul
echo wifi热点已经关闭，无法使用...
pause
goto caidan