51 汇编编程：使蜂鸣器发出“嘀、嘀。。。”报警声

对蜂鸣器控制，使蜂鸣器发出“嘀、嘀。。。”报警声。
报警声从 P1.3 端口输出，产生频率为 2.5KHz，声长 1.1 秒，间隔 1 秒。
晶振暂定12MHz。使用汇编语言编写。

题目链接：http://zhidao.baidu.com/question/568051065

要求发音频率是 2.5KHz，其半周期就是 200us。

可令单片机每隔 200us 中断一次。

每中断一次，就对 P1.3 取一次反，这就发出了 2.5KHz 方波。

取反 55 000 次，就是发音 1.1s。

再中断 50 000 次，不取反，就是发音间隔 1s。

中断的次数：50 000、55 000，可以用两个寄存器来计数。

定时 200us，可以使用方式2。

用汇编语言编写的程序如下：

    ORG   0000H
    JMP   MAIN
    ORG   000BH
    JMP   T0_INT      ;T0中断入口
;------------------------------------
MAIN:
    MOV   TMOD, #02H  ;T0定时方式2
    MOV   TH0, #56    ;200us @ 12MHz
    MOV   TL0, #56
    SETB  TR0         ;启动T0
    MOV   IE, #82H    ;允许T0中断
    MOV   R2, #100
    MOV   R3, #50     ;中断计数初始值
    SJMP  $           ;等待中断
;------------------------------------
T0_INT:
    JNB   F0, NO
    CPL   P1.3        ;发音
    DJNZ  R2, EXIT
    MOV   R2, #100
    DJNZ  R3, EXIT
    MOV   R3, #50     ;中断次数定为50000
    CPL   F0          ;下次中断，将不发音1s
    RETI
NO:
    SETB  P1.3        ;不发音
    DJNZ  R2, EXIT
    MOV   R2, #100
    DJNZ  R3, EXIT
    MOV   R3, #55     ;中断次数定为55000
    CPL   F0          ;下次中断，将发音1.1s
EXIT:
    RETI
;------------------------------------
END

本程序，已经经过了测试。

发音的频率，题目规定的是 2.5KHz，听起来，稍稍有些尖锐刺耳。

定时 200us 和发音 1.1s、静音 1s，做而论道仅仅使用了一个计数器T0，就解决了问题，这对于节省硬件资源，很有意义。

在回答这个题目的答案中，有人用上了两个定时/计数器，程序还长了许多，也没有满足题目的要求。
当然，把程序修改一下，还是可以的，但是，使用两个定时/计数器，这可不是正确的思路。

如果晶振频率改成 8MHz，分析如下：

输出的频率，题目要求是 2.5KHz，其半周期是 200us，必须定时 200us。

上面是用 12MHz 的晶振，机器周期是 1us，需要定时 200us，初值就是 256 - 200 = 56。

如果使用 8MHz 的晶振，机器周期是 1.5us，仍然定时 200us，初值就是 256 - 200/1.5 = 256 - 133 = 123。

把上面的程序中，有 56 的地方，改成 123，其它的，都不用改动。

这么改动之后，在 8MHz 的频率下，仍然是每隔 200us 中断一次。