安装OA的VBS脚本

'强制要求显式声明脚本中的所有变量
Option Explicit

'定义OA站点IP，分内外网
Const OA_URL_N="172.22.1.5"
Const OA_URL_W="192.168.90.11"

'选择内网还是外网
Dim strNet,strOA_Url
'默认外网
strNet="W"
strOA_Url=OA_URL_W

strNet=InputBox("N=内网，W=外网，默认是外网","选择网络","W")
If strNet = "w" or strNet = "W" Then
MsgBox("您选择的是外网，将建立外网OA。")
strOA_Url=OA_URL_W
ElseIf strNet = "n" or strNet = "N" Then
MsgBox("您选择的是内网，将建立内网OA。")
strOA_Url=OA_URL_N
Else
MsgBox("输入错误，脚本退出。")
Wscript.Quit
End If

'在收藏夹和桌面上添加站点
Dim WshShell,strDesktop,strFavorites,oUrlLink
'获得当前用户的桌面和收藏夹路径
Set WshShell = WScript.CreateObject("WScript.Shell")
strDesktop = WshShell.SpecialFolders("Desktop")
strFavorites = WshShell.SpecialFolders("Favorites")

'在收藏夹里创建OA的快捷方式
Set oUrlLink = WshShell.CreateShortcut(strFavorites & "\OA.url")
oUrlLink.TargetPath = "http://" & strOA_Url & ":20455"
oUrlLink.Save

'桌面创建OA的快捷方式
Set oUrlLink = WshShell.CreateShortcut(strDesktop & "\OA.url")
oUrlLink.TargetPath = "http://" & strOA_Url & ":20455"
oUrlLink.Save

'添加IE中的可信站点
MsgBox("添加IE中的可信站点")
Const HKEY_CURRENT_USER = &H80000001

Dim strComputer,objReg,strKeyPath,strValueName,strValue,dwValue

strComputer = "."
Set objReg = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")

'去掉"对该区域中的所有站点要求服务器验证"前面的勾
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2"
strValueName="Flags"
dwValue=67
objReg.SetDWORDValue HKEY_CURRENT_USER, strKeyPath, strValueName, dwValue

'创建注册表项
strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Ranges\Range9"
objReg.CreateKey HKEY_CURRENT_USER,strKeyPath

'创建注册表键并写入键值
strValueName=":Range"
strValue=strOA_Url
objReg.SetStringValue HKEY_CURRENT_USER, strKeyPath, strValueName, strValue

strValueName="http"
dwValue=2
objReg.SetDWORDValue HKEY_CURRENT_USER, strKeyPath, strValueName, dwValue

MsgBox("请注意，还需要修改IE的安全设置！")