您的位置：首页 > 数据库

SQL里实现类型String.Split()方法

2012-09-22 10:38 423 查看

题目有点标题党哈~不好意思，其实就是今天新学的一个小方法，分享一下给大家。

数据库中，总是遇到一些字段内容，想根据某个标识截取一下字符串，可是都想不到好办法，如果能有一个像ASP.NET里面的Split方法，那该多好，多方便啊！

为什么不可以？我们自己写一个函数不就可以解决了吗？好吧，说干就干，自己来写个SplitString函数！

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE function [dbo].[SplitString]
(
@Input nvarchar(max),
@Separator nvarchar(max)=',',
@RemoveEmptyEntries bit=1
)
returns @TABLE table
(
[Id] int identity(1,1),
[Value] nvarchar(max)
)
as
begin
declare @Index int, @Entry nvarchar(max)
set @Index = charindex(@Separator,@Input)

while (@Index>0)
begin
set @Entry=ltrim(rtrim(substring(@Input, 1, @Index-1)))

if (@RemoveEmptyEntries=0) or (@RemoveEmptyEntries=1 and @Entry<>'')
begin
insert into @TABLE([Value]) Values(@Entry)
end

set @Input = substring(@Input, @Index+datalength(@Separator)/2, len(@Input))
set @Index = charindex(@Separator, @Input)
end

set @Entry=ltrim(rtrim(@Input))
if (@RemoveEmptyEntries=0) or (@RemoveEmptyEntries=1 and @Entry<>'')
begin
insert into @TABLE([Value]) Values(@Entry)
end

return
end

函数、表都建好了，下面调用测试一下吧：

declare @str1 varchar(max), @str2 varchar(max), @str3 varchar(max)

set @str1 = '1,2,3'
set @str2 = '1###2###3'
set @str3 = '1###2###3###'

select [Value] from [dbo].[SplitString](@str1, ',', 1)
select [Value] from [dbo].[SplitString](@str2, '###', 1)
select [Value] from [dbo].[SplitString](@str3, '###', 0)

结果，截个图来看一下：

里面还有个自增的[Id]字段哦，在某些情况下有可能会用上的，例如根据Id来保存排序等等。

例如根据某表的ID保存排序：

update a set a.[Order]=t.[Id]
from [dbo].[表] as a join [dbo].SplitString('1,2,3', ',', 1) as t on a.[Id]=t.[Value]

内容来自用户分享和网络整理，不保证内容的准确性，如有侵权内容，可联系管理员处理

标签： sql input table insert asp.net function

相关文章推荐

新的分享

章节导航