ucos在s3c2410上运行过程整体剖析---两种任务切换的实现方法

以ucos为例，做详细说明。Ucos分为任务级任务切换和中断级任务切换。

Ucos整个用户程序和操作系统程序都运行在一个模式下（SVC模式）。所以在不用切换芯片运行模式的情况下就可以做任务级任务切换。

任务级进程切换原因是任务本身显示调用进程切换函数。

比如新建了一个优先级比较高的任务时就要显示调用任务切换函数。还有就是任务本身代码中调用了OSTimeDly（）函数时也会产生任务切换。当然，在切换之前一般先进行的是任务调度，关于调度算法这里就不再多说。

切换的具体过程：

OS_TASK_SW

STMFD sp!, {lr}; save pc。

//保存现场即保存下一条指令，下一条指令在lr中存储着返回的指令地址.

STMFD sp!, {lr} ; save lr//保存lr的值

STMFD sp!, {r0-r12} ; save registers //保存通用寄存器的值

MRS r4, CPSR ; cpsr寄存器只能用mrs 和 msr进行读写操作，前面说过整个代码运行在系统模式下，有读取cpsr寄存器的权限

STMFD sp!, {r4} ; save current CPSR //保存CPSR的值

MRS r4, SPSR

STMFD sp!, {r4} ; save SPSR //保存SPSR的值

到目前为止，我们已经把程序的运行环境保存到当前模式的任务堆栈中了

; OSPrioCur = OSPrioHighRdy

LDR r4, addr_OSPrioCur

LDR r5, addr_OSPrioHighRdy

LDRB r6, [r5]

STRB r6, [r4]

以上代码是把最高优先级复制给当前优先级

; Get current task TCB address

LDR r4, addr_OSTCBCur

LDR r5, [r4] ;提取tcb结构体里的首地址。即OSTCBStkPtr

STR sp, [r5] ; store sp in preempted tasks's TCB//把sp指针保存到OSTCBStkPtr指向的内容

到这里为止，已经把当前任务的相关信息都保存到当前任务的tcb中去了。

; Get highest priority task TCB address

LDR r6, addr_OSTCBHighRdy 把指向最高优先级任务tcb的指针赋给r6

LDR r6, [r6] 把最高优先级的TCB的首地址赋给r6（即任务堆栈指针的地址）

LDR sp, [r6] ; get new task's stack pointer 把新任务的堆栈指针内容赋给sp

; OSTCBCur = OSTCBHighRdy

STR r6, [r4] ; set new current task TCB addres //把最高优先级的任务控制块赋给当前任务的任务控制块

; restore task's mode regsiters

LDMFD sp!, {r4}

MSR SPSR_cxsf, r4

LDMFD sp!, {r4}

MSR CPSR_cxsf, r4

//恢复SPSR 和CPSR的内容

; return in new task context

LDMFD sp!, {r0-r12, lr, pc}

//恢复r0~r12，lr，pc值，当然程序也就跳转到新的任务执行了。

找到最高优先级的任务的任务控制块，由于任务控制块的第一个数据域是任务堆栈指针，

即偏移量是0的地方。取出该任务的任务堆栈，把里面保存的有关这个任务的信息恢复到当前所有的寄存器中。到此任务切换完成。

整个过程就是用指令强制当前进程切换成另一个进程。

需要注意的是，调用任务切换函数之前是已经关闭中断的了。即保存的CPSR的I和F位是1.

好了下面说一下，中断级任务切换。就是在中断服务程序里，如果发现了优先级更高的准备好运行的进程，那中断服务程序执行完后就不返回到原来的那个进程了，而是返回另一个更高优先级的进程。

; post FIQ Context switcher. This is called from OSIntExit when a hooked ISR

; wants to return in the context of another task. We load the new tasks context

; (from OSPrioHighRdy) and do the return from interrupt.

;

; Get pointer to stack where ISR_FiqHandler saved interrupted context

; ISR entry only saves first seven regs and LR.

;

;add r7, sp, #24 ; save pointer to register file, we must adjust this pointer to the position that just Enter Interrupt

LDR sp, =IRQStack ;IRQ_STACK ;test to del it

sub r7, sp, #4 ;r7 is the position that just Enter Interrupt; 进入中段运行模式后，堆栈中已经保存了被中断任务的pc 等相关寄存器，r7现在保存了堆栈的首地址。（因为ARM用的是递减的满堆栈）

; Change ARM CPU to SVC mode for stack operations.

; This gets the CPU off the interrupt stack and back to the

; interrupted task's stack, which is the one we want to alter.

;

mrs r1, SPSR ; get suspended PSR

orr r1, r1, #0xC0 ; disable IRQ, FIQ.

msr CPSR_cxsf, r1 ; switch mode (shold be SVC_MODE)

改变cpu到系统运行模式，目的是把在中断模式下保存的各种寄存器状态再保存到被中断的任务的任务控制块中，（主要是要把程序运行的状态保存到SVC模式下的堆栈中）

; PSR, SP, LR regs are now restored to the interrupted SVC_MODE.

; now set up the task's stack frame as OS_TASK_SW does...

;ldr r0, [r7, #52] ; get IRQ's LR (tasks PC) from IRQ stack //r0-r12

ldr r0, [r7] ; get IRQ's LR (tasks PC) from IRQ stack

sub r0, r0, #4 ; Actual PC address is (saved_LR - 4) 在中断时lr保存到pc是下两条到的指令地址，这和arm9的2级流水有关系

STMFD sp!, {r0} ; save task PC

STMFD sp!, {lr} ; save LR

sub lr, r7, #52 ;//we save the r0-r12 when we enter IRQ.

; mov lr, r7 ; save FIQ stack ptr in LR (going to nuke r7)

ldmfd lr!, {r0-r12} ; get saved registers from FIQ stack

STMFD sp!, {r0-r12} ; save registers on task stack //把中断发生时保存的r0~r12重新保存到SVC模式下的堆栈中

; save PSR and PSR for task on task's stack

MRS r4, CPSR

bic r4, r4, #0xC0 ; leave interrupt bits in enabled mode

STMFD sp!, {r4} ; save task's current PSR //保存的CPSR是开中断的

MRS r4, SPSR

STMFD sp!, {r4} ; SPSR too

到这里为止，已经把中断模式下保存的被中断的任务的相关寄存器的值又保存到SVC模式下的堆栈里了。

下面的切换过程和任务级的任务切换就一样了。

; OSPrioCur = OSPrioHighRdy // change the current process

LDR r4, addr_OSPrioCur

LDR r5, addr_OSPrioHighRdy

LDRB r6, [r5]

STRB r6, [r4]

; Get preempted tasks's TCB

LDR r4, addr_OSTCBCur

LDR r5, [r4]

STR sp, [r5] ; store sp in preempted tasks's TCB

到这里为止，已经把当前的任务执行环境保存到当前的任务控制块里了。

; Get new task TCB address

LDR r6, addr_OSTCBHighRdy

LDR r6, [r6]

LDR sp, [r6] ; get new task's stack pointer

; OSTCBCur = OSTCBHighRdy

STR r6, [r4] ; set new current task TCB address

LDMFD sp!, {r4}

MSR SPSR_cxsf, r4

LDMFD sp!, {r4}

BIC r4, r4, #0xC0 ; we must exit to new task with ints enabled//我们在任务级任务切换时保存的CPSR的I 和F位是禁止中断的，现在恢复时开中断。

MSR CPSR_cxsf, r4

LDMFD sp!, {r0-r12, lr, pc}

到这里中断级的任务切换就完成了。

和任务级任务切换惟一一点不同就是在进程切换的过程中有了模式的更改。

这点前面已经讲的很清楚了。我们应该把任务的执行环境保存到当前任务的任务堆栈里，而当放生中断级任务切换时，我们在中断模式下，因此我们应该切换运行模式再保存相关的内容。

分析完后，我们可以看出，在产生任务及任务切换时保存的CPSR是关闭中断的，而当被延时的任务恢复时是通过中断服务程序恢复的，恢复之前把中断打开。而在中断切换时保存的任务的CPSR是开中断的，恢复是通过任务级切换完成的。咱们的例子中被中断切换函数强制夺取CPU的只有空闲任务。

进程切换和模式切换有什么关系？

从上面的讲述也可以看出，模式的转换不一定引起进程的切换。模式是cpu硬件上对不同情况的执行环境的一种更改。而进程的切换是操作系统有目的的调度进程之间的运行，使其在时间上利用cpu最优化而已。

现在已经讲述了有关模式转换和进程切换的概念，并以ucos操作系统为实例进行了阐述。

关于操作系统具体怎么管理进程，大家看ucos已经掌握了最简单的只和任务有关的管理了。所谓管理进程也就是首先要知道进程的所有相关信息，在合理的时间和时机来更改这些属性罢了。

到这里为止，我们已经大致上分析完了一个实时操作系统具体怎么运行的了。

前面分析了什么是进程，进程就是一个能在cpu正常运行的指令流程，它是一个整体。我们已经知道了怎么把他们看成整体来管理他们了，但有时候我们可能还需要进行进程间的通讯。

关于这些内容，ucos提供了信号量、消息邮箱、事件组标志等。

关于这些内容比较容易理解，我们就不一一分析了，我们已经掌握了核心的东东，这些应该很容易看懂得。关于并发的更多内容可以看操作系统之并发.doc

好了，一下子写这么多字，还是第一次。这些都是想到哪写到哪的东西，思路可能比较乱，但我对ucos的理解大致上都写了。希望对初学者有一些帮助。有时间我会一一整理，使其更规范，更易读。

张连聘
2012年2月18日星期
计算机系系统结构教研室