【转】浅谈Object Pascal的指针

其实，Pascal语言本身也是支持指针的。从最初的Pascal发展至今的Object Pascal，可以说在指针运用上，丝毫不会逊色于C语言的指针。
以下内容分为8个部分，分别是：
1 类型指针的定义
2 无类型指针的定义
3 指针的解除引用
4 取地址（指针赋值）
5 指针运算
6 动态内存分配
7 字符数组的运算
8 函数指针 1．类型指针的定义
对于指向特定类型的指针，在C语言中是这样定义的：
int *ptr;
char *ptr;
与之等价的Object Pascal又是如何定义的呢？
var ptr : ^Integer;
ptr : ^char;
其实也就是符号的差别而已。
2．无类型指针的定义
C中有void *类型，也就是可以指向任何类型数据的指针。Object Pascal为其定义了一个专门的类型——Pointer。于是， Delphi 高手突破
ptr : Pointer;
就与C语言中的
void *ptr;
等价了。
3．指针的解除引用
要解除指针引用（即取出指针所指区域的值），C语言的语法是(*ptr)，Object Pascal则 是ptr^。
4．取地址（指针赋值）
取某对象的地址并将其赋值给指针变量，C语言的语法是：
ptr = &Object;
Object Pascal则是：
ptr := @Object;
也只是符号的差别而已。
5．指针运算
在C语言中，可以对指针进行移动的运算，如：
char a[20];
char *ptr=a;
ptr++;
ptr+=2;
当执行ptr++;时，编译器会产生让ptr前进sizeof(char)步长的代码，之后，ptr将指向a[1]。ptr+=2;这句使得ptr前进两个sizeof(char)大小的步长。同样，来看一下Object Pascal中如何实现：
var
a : array [1..20] of Char;
ptr : PChar; // PChar可以看作^Char
begin
ptr := @a;
Inc(ptr); // 这句等价于语言C的ptr++;
Inc(ptr, 2); // 这句等价于语言C的ptr+=2;
end;
6．动态内存分配
在C语言中，使用malloc()库函数分配内存，free()函数释放内存。如这样的代码：
int *ptr, *ptr2;
int i;
ptr = (int*) malloc(sizeof(int) * 20);
ptr2 = ptr;
for (i=0; i<20; i++){
*ptr = i; ptr++;
}
free(ptr2);
Object Pascal中，动态分配内存的函数是GetMem()，与之对应的释放函数为FreeMem()（传统的Pascal中获取内存的函数是New()和Dispose()，但New()只能获得对象的单个实体的内存大小，无法取得连续的存放多个对象的内存块）。因此，与上面那段C语言的代码等价的Object Pascal的代码为：
var
ptr, ptr2 : ^integer;
i : integer;
begin
GetMem(ptr, sizeof(integer) * 20);
//这句等价于C的 ptr = (int*) malloc(sizeof(int) * 20);
ptr2 := ptr; //保留原始指针位置
for i := 0 to 19 do
begin
ptr^ := i;
Inc(ptr);
end;
FreeMem(ptr2);
end;
对于以上这个例子（无论是C版本的，还是Object Pascal版本的），都要注意一个问题，就是分配内存的单位是字节（Byte），因此在使用GetMem时，其第2个参数如果想当然地写成20，那么就会出问题了（内存访问越界）。因为GetMem(ptr, 20);实际只分配了20个字节的内存空间，而一个整形的大小是4个字节，那么访问第5个之后的所有元素都是非法的了（对于malloc()的参数同样）。
7．字符数组的运算
C语言中是没有字符串类型的，因此，字符串都是用字符数组来实现，于是也有一套str打头的库函数以进行字符数组的运算。如以下代码：
char str[15];
char *pstr;
strcpy(str, "teststr");
strcat(str, "_testok");
pstr = (char*) malloc(sizeof(char) * 15);
strcpy(pstr, str);
printf(pstr);
free(pstr);
而在Object Pascal中因为有了String类型，因此可以很方便地对字符串进行各种运算。但是，有时我们的Pascal代码需要与C语言的代码交互（例如，用Object Pascal的代码调用C语言编写的DLL或者用Object Pascal编写的DLL准备允许用C语言编写客户端的代码），就不能使用String类型了，而必须使用两种语言通用的字符数组。其实，Object Pascal提供了完全类似C语言的一整套字符数组的运算函数。以上那段代码的Object Pascal版本是这样的：
var
str : array [1..15] of char;
pstr : PChar; //Pchar 也就是 ^Char
begin
StrCopy(@str, 'teststr');
// 在C语言中，数组的名称可以直接作为数组首地址指针来用
// 但Pascal不是这样的，因此str前要加上取址运算符
// 但如果数组是以0为起始下标，则与C语言一样，可以数组名称作为数组首地址
StrCat(@str, '_testok');
GetMem(pstr, sizeof(char) * 15);
StrCopy(pstr, @str);
Write(pstr);
FreeMem(pstr);
end;
8．函数指针
在动态调用DLL中的函数时，就会用到函数指针。假设用C语言编写的一段代码如下：
typedef int (*PVFN)(int); //定义函数指针类型
int main()
{
HMODULE hModule = LoadLibrary("test.dll");
PVFN pvfn = NULL;
pvfn = (PVFN) GetProcAddress(hModule, "Function1");
pvfn(2);
FreeLibrary(hModule);
}
就笔者个人感觉来说，C语言中定义函数指针类型的typedef代码的语法有些晦涩，而同样的代码在Object Pascal中却非常易懂：
type PVFN = Function (para : Integer) : Integer;
var
fn : PVFN;
// 也可以直接在此处定义，如：fn : function (para:Integer):Integer;
hDLL : HMODULE;
begin
hDLL := LoadLibrary('test.dll');
fn := GetProcAddress(hDLL, 'Function1');
fn(2);
FreeLibrary(hDLL);
end;