【学习笔记】自己动手写操作系统--pmtest1

Code
; ==========================================
; pmtest1.asm
; 编译方法：nasm pmtest1.asm -o pmtest1.com
; ==========================================

%INCLUDE "pm.inc" ; 常量, 宏, 以及一些说明

ORG 0100h
JMP LABEL_BEGIN

[SECTION .gdt]
; GDT
; 段基址, 段界限 , 属性
LABEL_GDT: Descriptor 0, 0, 0 ; 空描述符
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len - 1, DA_C + DA_32 ; 非一致代码段, 32
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh, DA_DRW ; 显存首地址
; GDT 结束

GdtLen EQU $ - LABEL_GDT ; GDT长度
GdtPtr DW GdtLen - 1 ; GDT界限 定义GdtPtr的数据结构
DD 0 ; GDT基地址

; GDT 选择子
SelectorCode32 EQU LABEL_DESC_CODE32 - LABEL_GDT
SelectorVideo EQU LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]

[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
MOV AX, CS ; 默认启动时候cs为0
MOV DS, AX
MOV ES, AX
MOV SS, AX
MOV SP, 0100h

; 初始化 32 位代码段描述符，把LABEL_SEG_CODE32中地址值（CS+偏移）的每个字节分别复制给LABEL_DESC_CODE32对应得2，4，7号字节位置
XOR EAX, EAX
MOV AX, CS
SHL EAX, 4
ADD EAX, LABEL_SEG_CODE32
MOV WORD [LABEL_DESC_CODE32 + 2], AX
SHR EAX, 16
MOV BYTE [LABEL_DESC_CODE32 + 4], AL
MOV BYTE [LABEL_DESC_CODE32 + 7], AH

; 为加载 GDTR 作准备，得到GdtPtr 的地址，也就是Gdtprt数据结构的地址，对第二个“属性”赋值，为Gdt的数据结构的首地址
XOR EAX, EAX
MOV AX, DS
SHL EAX, 4
ADD EAX, LABEL_GDT ; eax <- gdt 基地址
MOV dword [GdtPtr + 2], EAX ; [GdtPtr + 2] <- gdt 基地址

; 加载 GDTR
lgdt [GdtPtr]

; 关中断
CLI

; 打开地址线A20
IN AL, 92h
OR AL, 00000010b
OUT 92h, AL

; 准备切换到保护模式
MOV EAX, cr0
OR EAX, 1
MOV cr0, EAX

; 真正进入保护模式
JMP dword SelectorCode32:0 ; 执行这一句会把 SelectorCode32 装入 cs, 并跳转到 Code32Selector:0 处
; END of [SECTION .s16]

[SECTION .s32]; 32 位代码段. 由实模式跳入.
[BITS 32]

LABEL_SEG_CODE32:
MOV AX, SelectorVideo
MOV gs, AX ; 视频段选择子(目的)

MOV EDI, (80 * 10 + 0) * 2 ; 屏幕第 10 行, 第 0 列。
MOV AH, 0Ch ; 0000: 黑底 1100: 红字
MOV AL, 'P'
MOV [gs:EDI], AX

; 到此停止
JMP $

SegCode32Len EQU $ - LABEL_SEG_CODE32
; END of [SECTION .s32]