使用 Excel 2003 工作表的 VBA 示例

Sub QuoteCommaExport()
Dim DestFile As String
Dim FileNum As Integer
Dim ColumnCount As Integer
Dim RowCount As Integer

' 提示用户指定目标文件名。
DestFile = InputBox("Enter the destination filename" & _
Chr(10) & "(with complete path and extension):", _
"Quote-Comma Exporter")
' 获取下一个可用的文件句柄编号。
FileNum = FreeFile()

' 关闭错误检查功能。
On Error Resume Next

' 尝试打开目标文件以供输出。
Open DestFile For Output As #FileNum
' 如果出现错误，则报告错误并结束程序。
If Err <> 0 Then
MsgBox "Cannot open filename " & DestFile
End
End If

' 打开错误检查功能。
On Error GoTo 0

' 循环选择的每一行。
For RowCount = 1 To Selection.Rows.Count
' 循环选择的每一列。
For ColumnCount = 1 To Selection.Columns.Count

' 将当前单元格中的文本写入到文件中，文本用引号括起来。
Print #FileNum, """" & Selection.Cells(RowCount, _
ColumnCount).Text & """";
' 检查单元格是否位于最后一列。
If ColumnCount = Selection.Columns.Count Then
' 如果是，则写入一个空行。
Print #FileNum,
Else
' 否则，则写入一个逗号。
Print #FileNum, ",";
End If
' 开始 ColumnCount 循环的下一个迭代。
Next ColumnCount
' 开始 RowCount 循环的下一个迭代。
Next RowCount

' 关闭目标文件。
Close #FileNum
End Sub

Sub TotalRowsAndColumns()
' 此宏假定您已从
' 要计算单元格总数的矩形区域内
' 选择了一个单元格或一组单元格。行和列的单元格总数将出现在
' 当前区域下面的行和右侧的列中。

Dim r As Integer
Dim c As Integer
Dim i As Integer
Dim j As Integer
Dim myArray As Variant

' 将 myArray 声明为变量将使数组可以接收
' 一组单元格。此时，数组将自动转换为
' 以下标 myArray(1,1) 开始的数组。

' 指当前所选单元格周围的区域。
With Selection.CurrentRegion
r = .Rows.Count
c = .Columns.Count
' 重新计算总行数和总列数并将结果存储到数组中。
myArray = .Resize(r + 1, c + 1)

' 在下面的嵌套循环中，变量 i 跟踪
' 行号，变量 j 跟踪
' 列号。j 在可用列中每循环一次，
' i 就递增一，而 j
' 则重新从一到 c 循环一次。
For i = 1 To r
For j = 1 To c
' 行 i 的总数
myArray(i, c + 1) = myArray(i, c + 1) + myArray(i, j)
' 列 j 的总数
myArray(r + 1, j) = myArray(r + 1, j) + myArray(i, j)
' 总计
myArray(r + 1, c + 1) = myArray(r + 1, c + 1) + myArray(i, j)
Next j
Next i

' 将数组返回工作表，数组中现在包含一个
' 新行和一个新列，用于存储总数。
.Resize(r + 1, c + 1) = myArray
End With
End Sub