设计模式、用Delphi实现---->Singleton 模式

Singleton模式

起源

Delphi的SINGLETON模式是在SINGLETON的基础上进行了扩展。更多SINGLETON模式的资料请参阅 《设计模式84页》<?xml:namespace prefix = o ns = "urn:schemas-microsoft-com:office:office" />

目的

保证一个类仅有一个实例，并提供一个访问它的全局访问点，一个相对简单的应用型设计模式

动机

此模式最重要的是保证大量类正确的访问单个实例。尽管一台个系统可能有多台打印机，但系统只允许有且只有一个打印缓存。同样比如：一个系统只有一个文件系统、一个窗体管理系统。对于Delphi的VCL来说：大家天天接触的Tapplication，Tscreen，Tclipboard都是。此模式更好的是使你可以在任何时候为你的应用程序提供一个全局对象。其它的用途：可以、提供一些全局的异常句柄，安全控制，为跨进程提供单一的访问点。
怎样保持一个类只有一个实例并且建立好的访问性能？一个全局变量保证了实例的可访问性，但还没有保证多个实例的同时存大的可能。
一个好的解决方案：建立类自身来负责保持自身一个实例的机制。类的第一个实例能保存不会再有类的实例被创建（在创建类的新实例时请求被中段）。并提供一个访问类的方法。这就是我们的singleton模式，典型的应用是建立服务型的的类。
 

应用

假设有一个用于显示时间进度低级服务类Tprogressor。类包括两个典型的方法：StartProgress, EndProgress, Abort 和一些常用的属性如：Progress, Aborted其它。
下面代码是Tprogressor类的接口部份
type
  TProgressor = class (TObject)
  private
    FProgress: Integer;
  protected
    procedure SetProgress(Value: Integer);
  public
»   procedure StartProgress;
»   property Progress: Integer read FProgress write SetProgress;
  end;
 

下面的代码是应用了singleton模式后的类的的接口部份。
type
  TProgressor = class (TObject)
  private
    FProgress: Integer;
  protected
    constructor CreateInstance;
    class function AccessInstance(Request: Integer): TProgressor;
    procedure SetProgress(Value: Integer);
  public
    constructor Create;
    destructor Destroy; override;
    class function Instance: TProgressor;
    class procedure ReleaseInstance;
»   procedure StartProgress;
»   property Progress: Integer read FProgress write SetProgress;
  end;
 

类接口部份的介绍：
·      方法class function Instance用于访问类的单件的实例。此方法一般在第一时间访问，类的实例被创建。
·      类构造器被重载，如果你尝试着不通过instance方法来构建一个新的实例将会抛出一个异常。
·      可通过调用ReleaseInstance来清除单件类存在的实例。一般在你要清除部件时调节器用些方法。在Delphi 1 exit过程中调用，在Delphi 2/3/4/5/6中在单元finalization中调用。不要访问TProgressor.Instance.Free来清除实例，
 

现在让我们来看看singleton模式实现。
constructor TProgressor.Create;
begin
  inherited Create;
  raise Exception.CreateFmt('Access class %s through Instance only',
      [ClassName]);
end;
 

constructor TProgressor.CreateInstance;
begin
  inherited Create;
end;
 

destructor TProgressor.Destroy;
begin
  if AccessInstance(0) = Self then AccessInstance(2);
  inherited Destroy;
end;
 

class function TProgressor.AccessInstance(Request: Integer): TProgressor;
  const FInstance: TProgressor = nil;
begin
  case Request of
    0 : ;
    1 : if not Assigned(FInstance) then FInstance := CreateInstance;
    2 : FInstance := nil;
  else
    raise Exception.CreateFmt('Illegal request %d in AccessInstance',
        [Request]);
  end;
  Result := FInstance;
end;
 

class function TProgressor.Instance: TProgressor;
begin
  Result := AccessInstance(1);
end;
 

class procedure TProgressor.ReleaseInstance;
begin
  AccessInstance(0).Free;
end;
 

procedure TProgressor.SetProgress(Value: Integer);
begin
»加入实现代码
end;
 

procedure TProgressor.StartProgress;
begin
»加入实现代码
end;
 

此模式的密秘在AccessInstance方法，AccessInstance方法使用了常量来存放实例。

由于Delphi不支持静态类字段的原因，你必需使用此方法。AccessInstance根据请求的参数来确认不同的返回方式，返回当前实例（Request = 0），创建一个实例(Request = 1)，重置实例（Request = 2）。Delphi 2/3/4/5/6中，你必须将编译器设置$J+来支持形式常量（参见Delphi在线帮助）
将CreateInstance设成保护方法（protected），我们确保了其它类不能调用类的构造器。但由于构造函数本身为虚函数的原因，它可以被后代重载。例中，当第一次调用类实例时将确认类的具体类型。
唯一需要你手动添加的代码是：在单元的initialization或finalization加入清除代码。
下面是应用实例（Delphi1.0）
 

unit ProgressorTest;
 

...
...
 

implementation
 

...
...
 

procedure ShutDown; far;
begin
» TProgressor.ReleaseInstance;
end;
 

initialization
MMWIN:START INITIALIZATION
» AddExitProc(ShutDown);
end.
 

具体操作Tprogressor的代码:
 

procedure TSomeClass.DoSomething;
var I: Integer;
begin
» TProgressor.Instance.StartProgress;
» for I := 0 to 100 do
» begin
»   TProgressor.Instance.Progress := I;
» ..{ 完成其它的工作}
» end;
» TProgressor.Instance.EndProgress;
end;

Delphi实例

正在组织